import java.util.*
 
 
android {
 
    // 省略
    
    // APK作成と署名の設定
    signingConfigs {
        // 環境変数から取りに行く
        create("release_signing_config") {
            // 存在しない場合はとりあえずスルーする
            if (System.getenv("ENV_SIGN_KEYSTORE_BASE64") != null) {
                // GitHubActionsの環境変数に入れておいた署名ファイルがBase64でエンコードされているので戻す
                System.getenv("ENV_SIGN_KEYSTORE_BASE64").let { base64 ->
                    val decoder = Base64.getDecoder()
                    // ルートフォルダに作成する
                    File("keystore.jks").also { file ->
                        file.createNewFile()
                        file.writeBytes(decoder.decode(base64))
                    }
                }
                // どうやら appフォルダ の中を見に行ってるみたいなのでプロジェクトのルートフォルダを指定する
                storeFile = File(rootProject.projectDir, "keystore.jks")
                keyAlias = System.getenv("ENV_SIGN_KEY_ALIAS")
                keyPassword = System.getenv("ENV_SIGN_KEY_PASSWORD")
                storePassword = System.getenv("ENV_SIGN_STORE_PASSWORD")
            }
        }
    }
 
    buildTypes {
        release {
            // 署名の設定を適用する
            signingConfig = signingConfigs.getByName("release_signing_config")
            isMinifyEnabled = false
            proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro")
        }
    }
 
}

name: Generate Release APK
 
on:
  # releaseブランチ更新時に起動する
  push:
    branches: [ release ]
  # 手動実行ボタン
  workflow_dispatch:
    
jobs:
  build:
 
    runs-on: ubuntu-latest
 
    steps:
    
    # releaseブランチをチェックアウト
    - uses: actions/checkout@v2
      with:
        ref: 'release'
 
    # JDK導入
    - name: set up JDK 11
      uses: actions/setup-java@v2
      with:
        java-version: '11'
        distribution: 'temurin'
        cache: gradle
    
    # 権限を与える
    - name: Grant permission gradlew
      run: chmod +x gradlew
      
    # コマンドラインからAPKの作成。実行前に環境変数をGitHubActionsのSecretから取得
    - name: Building APK
      env:
        ENV_SIGN_KEYSTORE_BASE64: ${{secrets.ENV_SIGN_KEYSTORE_BASE64}}
        ENV_SIGN_KEY_ALIAS: ${{secrets.ENV_SIGN_KEY_ALIAS}}
        ENV_SIGN_KEY_PASSWORD: ${{secrets.ENV_SIGN_KEY_PASSWORD}}
        ENV_SIGN_STORE_PASSWORD: ${{secrets.ENV_SIGN_STORE_PASSWORD}}
      run: ./gradlew assembleRelease
 
    # アーティファクトとして保存
    - name: Upload artifact
      uses: actions/upload-artifact@v2
      with:
        name: app-release.apk
        path: app/build/outputs/apk/release/app-release.apk

set ENV_SIGN_KEYSTORE_BASE64 = {Base64にした署名ファイル}
set ENV_SIGN_KEY_ALIAS = {Key alias}
set ENV_SIGN_KEY_PASSWORD = {Key password}
set ENV_SIGN_STORE_PASSWORD = {Key store password}

// トップレベル (appフォルダじゃない) build.gradle.kts
 
// Top-level build file where you can add configuration options common to all sub-projects/modules.
plugins {
    id("com.android.application").version("7.1.0").apply(false)
    id("com.android.library").version("7.1.0").apply(false)
    id("org.jetbrains.kotlin.android").version("1.6.10").apply(false)
}
 
tasks.register("clean") {
    doFirst {
        delete(rootProject.buildDir)
    }
}

// appフォルダ内 build.gradle.kts
 
import java.util.*
 
plugins {
    id("com.android.application")
    id("kotlin-android")
    id("kotlin-kapt")
}
 
android {
    compileSdk = 31
 
    defaultConfig {
        applicationId = "io.github.takusan23.chocodroid"
        minSdk = 21
        targetSdk = 31
        versionCode = 1
        versionName = "1.0.0"
 
        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
    }
 
    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8
    }
    kotlinOptions {
        jvmTarget = "1.8"
    }
    buildFeatures {
        viewBinding = true
    }
 
    // APK作成と署名の設定
    signingConfigs {
        /**
         * 予め GitHubActions の環境変数に入れておく
         *
         * ローカル環境で行う場合 (Windows cmd.exe)
         *
         * set ENV_SIGN_KEYSTORE_BASE64 = Base64エンコードした署名ファイル
         * set ENV_SIGN_KEY_ALIAS = KeyAlias
         * set ENV_SIGN_KEY_PASSWORD = KeyPassword
         * set ENV_SIGN_STORE_PASSWORD = StorePassword
         * */
        create("release_signing_config") {
            // 存在しない場合はとりあえずスルーする
            if (System.getenv("ENV_SIGN_KEYSTORE_BASE64") != null) {
                // GitHubActionsの環境変数に入れておいた署名ファイルがBase64でエンコードされているので戻す
                System.getenv("ENV_SIGN_KEYSTORE_BASE64").let { base64 ->
                    val decoder = Base64.getDecoder()
                    // ルートフォルダに作成する
                    File("keystore.jks").also { file ->
                        file.createNewFile()
                        file.writeBytes(decoder.decode(base64))
                    }
                }
                // どうやら appフォルダ の中を見に行ってるみたいなのでプロジェクトのルートフォルダを指定する
                storeFile = File(rootProject.projectDir, "keystore.jks")
                keyAlias = System.getenv("ENV_SIGN_KEY_ALIAS")
                keyPassword = System.getenv("ENV_SIGN_KEY_PASSWORD")
                storePassword = System.getenv("ENV_SIGN_STORE_PASSWORD")
            }
        }
    }
 
    buildTypes {
        release {
            // 署名の設定を適用する
            signingConfig = signingConfigs.getByName("release_signing_config")
            isMinifyEnabled = false
            proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro")
        }
    }
 
}
 
dependencies {
  implementation("androidx.core:core-ktx:1.7.0")
  implementation("androidx.appcompat:appcompat:1.4.0")
  implementation("com.google.android.material:material:1.4.0")
  implementation("androidx.constraintlayout:constraintlayout:2.1.1")
  testImplementation("junit:junit:4.13.2")
  androidTestImplementation("androidx.test.ext:junit:1.1.3")
  androidTestImplementation("androidx.test.espresso:espresso-core:3.4.0")
}