gpg --keyserver keyserver.ubuntu.com --send-keys <コピーした16進数>

gpg --export-secret-keys コピーした16進数 > export_secret
certutil -f -encode export_secret export_secret_base64

buildscript {
    val kotlinVersion: String by extra("1.7.10")
    val composeVersion: String by extra("1.3.1")
}
// Top-level build file where you can add configuration options common to all sub-projects/modules.
plugins {
    id("com.android.application").version("7.4.0").apply(false)
    id("com.android.library").version("7.4.0").apply(false)
    id("org.jetbrains.kotlin.android").version("1.7.10").apply(false)
    // ドキュメント生成と Maven Central へ公開をしてくれるやつ
    id("org.jetbrains.dokka").version("1.7.10")
    id("io.github.gradle-nexus.publish-plugin").version("1.1.0")
}
 
tasks.register("clean") {
    doFirst {
        delete(rootProject.buildDir)
    }
}
 
// ライブラリ署名情報がなくてもビルドできるようにする
extra["signing.keyId"] = ""
extra["signing.password"] = ""
extra["signing.key"] = ""
extra["ossrhUsername"] = ""
extra["ossrhPassword"] = ""
extra["sonatypeStagingProfileId"] = ""
 
// 署名情報を読み出す。開発環境では local.properties に署名情報を置いている。
val secretPropsFile = project.rootProject.file("local.properties")
if (secretPropsFile.exists()) {
    // 読み出して、extra へ格納する
    val properties = java.util.Properties().apply {
        load(secretPropsFile.inputStream())
    }
    properties.forEach { name, value -> extra[name as String] = value }
} else {
    // システム環境変数から読み出す。CI/CD 用
    extra["ossrhUsername"] = System.getenv("OSSRH_USERNAME")
    extra["ossrhPassword"] = System.getenv("OSSRH_PASSWORD")
    extra["sonatypeStagingProfileId"] = System.getenv("SONATYPE_STAGING_PROFILE_ID")
    extra["signing.keyId"] = System.getenv("SIGNING_KEY_ID")
    extra["signing.password"] = System.getenv("SIGNING_PASSWORD")
    extra["signing.key"] = System.getenv("SIGNING_KEY")
}
 
// Sonatype OSSRH リポジトリ情報
nexusPublishing.repositories.sonatype {
    stagingProfileId.set(extra["sonatypeStagingProfileId"] as String)
    username.set(extra["ossrhUsername"] as String)
    password.set(extra["ossrhPassword"] as String)
    nexusUrl.set(uri("https://s01.oss.sonatype.org/service/local/"))
    snapshotRepositoryUrl.set(uri("https://s01.oss.sonatype.org/content/repositories/snapshots/"))
}

plugins {
    id("com.android.library")
    id("org.jetbrains.kotlin.android")
    // ライブラリに同梱するドキュメント生成器
    id("org.jetbrains.dokka")
    // ライブラリ作成に必要
    `maven-publish`
    signing
}
 
// ライブラリバージョン
val libraryVersion = "1.0.2"
// ライブラリ名
val libraryName = "conecocore"
// ライブラリの説明
val libraryDescription = "It is a library that connects multiple videos into one."
 
android {
    compileSdk = 33
    namespace = "io.github.takusan23.conecocore"
 
    defaultConfig {
        minSdk = 21
        targetSdk = 33
 
        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
        consumerProguardFile("consumer-rules.pro")
    }
 
    buildTypes {
        release {
            isMinifyEnabled = false
            proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro")
        }
    }
    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8
    }
    kotlinOptions {
        jvmTarget = "1.8"
    }
}
 
dependencies {
 
    implementation("org.jetbrains.kotlinx:kotlinx-coroutines-android:1.6.0")
 
    implementation("androidx.core:core-ktx:1.7.0")
    implementation("androidx.appcompat:appcompat:1.4.1")
 
    testImplementation("junit:junit:4.13.2")
    androidTestImplementation("androidx.test.ext:junit:1.1.3")
    androidTestImplementation("androidx.test.espresso:espresso-core:3.4.0")
}
 
val androidSourcesJar = tasks.register<Jar>("androidSourcesJar") {
    archiveClassifier.set("sources")
    from(android.sourceSets["main"].java.srcDirs)
}
 
tasks.dokkaJavadoc {
    outputDirectory.set(File(buildDir, "dokkaJavadoc"))
}
 
val javadocJar = tasks.register<Jar>("dokkaJavadocJar") {
    dependsOn(tasks.dokkaJavadoc)
    from(tasks.dokkaJavadoc.flatMap { it.outputDirectory })
    archiveClassifier.set("javadoc")
}
 
artifacts {
    archives(androidSourcesJar)
    archives(javadocJar)
}
 
signing {
    // ルート build.gradle.kts の extra を見に行く
    useInMemoryPgpKeys(
        rootProject.extra["signing.keyId"] as String,
        rootProject.extra["signing.key"] as String,
        rootProject.extra["signing.password"] as String,
    )
    sign(publishing.publications)
}
 
afterEvaluate {
    publishing {
        publications {
            create<MavenPublication>("maven") {
                groupId = "io.github.takusan23"
                artifactId = libraryName
                version = libraryVersion
                if (project.plugins.hasPlugin("com.android.library")) {
                    from(components["release"])
                } else {
                    from(components["java"])
                }
                artifact(androidSourcesJar)
                artifact(javadocJar)
                pom {
                    // ライブラリ情報
                    name.set(artifactId)
                    description.set(libraryDescription)
                    url.set("https://github.com/takusan23/Coneco/")
                    // ライセンス
                    licenses {
                        license {
                            name.set("Apache License 2.0")
                            url.set("https://github.com/takusan23/Coneco/blob/master/LICENSE")
                        }
                    }
                    // 開発者
                    developers {
                        developer {
                            id.set("takusan_23")
                            name.set("takusan_23")
                            url.set("https://takusan.negitoro.dev/")
                        }
                    }
                    // git
                    scm {
                        connection.set("scm:git:github.com/takusan23/Coneco")
                        developerConnection.set("scm:git:ssh://github.com/takusan23/Coneco")
                        url.set("https://github.com/takusan23/Coneco")
                    }
                }
            }
        }
    }
}

plugins {
     alias(libs.plugins.kotlin.android).apply(false)
     // akaricore ライブラリ公開で使う
     alias(libs.plugins.gradle.nexus.publish.plugin)
-    alias(libs.plugins.jetpbrains.dokka)
-}
-
-subprojects {
-    apply(plugin = "org.jetbrains.dokka")
 }

plugins {
    id("com.android.library")
    id("org.jetbrains.kotlin.android")
    // Maven Central に公開する際に利用
    `maven-publish`
    signing
}
 
// ライブラリ公開は Android でも言及するようになったので目を通すといいかも
// https://developer.android.com/build/publish-library/upload-library
// そのほか役に立ちそうなドキュメント
// https://docs.gradle.org/current/dsl/org.gradle.api.publish.maven.MavenPublication.html
// https://github.com/gradle-nexus/publish-plugin
 
// OSSRH にアップロードせずに成果物を確認する方法があります。ローカルに吐き出せばいい
// gradle :akari-core:publishToMavenLocal
 
android {
    namespace = "io.github.takusan23.akaricore"
    compileSdk = 34
 
    defaultConfig {
        minSdk = 21
        targetSdk = 34
 
        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
        consumerProguardFiles("consumer-rules.pro")
    }
 
    buildTypes {
        release {
            isMinifyEnabled = false
            proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro")
        }
    }
    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8
    }
    kotlinOptions {
        jvmTarget = "1.8"
    }
 
    // どうやら Android Gradle Plugin 側で sources.jar と javadoc.jar を作る機能が実装されたそう
    publishing {
        singleVariant("release") {
            withSourcesJar()
            withJavadocJar()
        }
    }
}
 
// ライブラリ
dependencies {
 
    implementation(libs.androidx.core)
    implementation(libs.androidx.appcompat)
    implementation(libs.kotlinx.coroutine)
    testImplementation(libs.junit)
    androidTestImplementation(libs.kotlinx.coroutine.test)
    androidTestImplementation(libs.androidx.test.junit)
    androidTestImplementation(libs.androidx.test.espresso.core)
}
 
// ライブラリのメタデータ
publishing {
    publications {
        create<MavenPublication>("release") {
            groupId = "io.github.takusan23"
            artifactId = "akaricore"
            version = "2.0.0-alpha01"
 
            // afterEvaluate しないとエラーなる
            afterEvaluate {
                from(components["release"])
            }
 
            pom {
                // ライブラリ情報
                name.set("akaricore")
                description.set("AkariDroid is Video editor app in Android. AkariDroid core library")
                url.set("https://github.com/takusan23/AkariDroid/")
                // ライセンス
                licenses {
                    license {
                        name.set("Apache License 2.0")
                        url.set("https://github.com/takusan23/AkariDroid/blob/master/LICENSE")
                    }
                }
                // 開発者
                developers {
                    developer {
                        id.set("takusan_23")
                        name.set("takusan_23")
                        url.set("https://takusan.negitoro.dev/")
                    }
                }
                // git
                scm {
                    connection.set("scm:git:github.com/takusan23/AkariDroid")
                    developerConnection.set("scm:git:ssh://github.com/takusan23/AkariDroid")
                    url.set("https://github.com/takusan23/AkariDroid")
                }
            }
        }
    }
}
 
// 署名
signing {
    // ルート build.gradle.kts の extra を見に行く
    useInMemoryPgpKeys(
        rootProject.extra["signing.keyId"] as String,
        rootProject.extra["signing.key"] as String,
        rootProject.extra["signing.password"] as String,
    )
    sign(publishing.publications["release"])
}

# Git管理下に入れてはぜっっったいダメです
# 絶対秘密です
# 鍵IDの最後8桁
signing.keyId=xxxxxx
# パスワード
signing.password=password
# 秘密鍵のBase64
signing.key=xxxxxxxxx
# Sonatype OSSRH のユーザー名
ossrhUsername=takusan_23
# Sonatype OSSRH のパスワード
ossrhPassword=password
# Sonatype ステージングプロファイルId
sonatypeStagingProfileId=8320....

// build.gradle
implementation 'io.github.takusan23:conecocore:1.0.0'
 
// build.gradle.kts の場合
implementation("io.github.takusan23:conecocore:1.0.0")